Для всего этого безобразия нам потребуется куча классов которые я навыкладывал в предыдущих сериях, а именно Cookie.as, ageMath.as, ageVector.as, sounds.as, alphaFader.as. Все они уже есть в исходниках примера, так что отдельно качать ничего не надо.

Да я знаю что практика таскания кучи библиотек многим не по душе, однако я хочу отметить – я даю готовые решения, а не делаю уроки так что этот беспредел будет и дальше продолжаться. Я вообще подумываю собрать все наработки в какое-то подобие фреймворка, точнее даже темплейта, который можно будет загрузить и уже на основе него ваять новую игрушку

Ну ладна, от лирики к нашим баранам, то есть ачивкам.

Сразу смотрим как это работает:

Первые три кнопки – получение ачивки, последняя кнопка очищает все набранные достижения.

Все ачивки делятся на два типа – обычные и с параметром.
Обычные – это такие, которые получаешь за определённое действие, например пройти первый уровень.
С параметром – это когда например чтобы получить ачивку надо убить 5 монстров. Все текущие значения сохраняются внутри движка ачивок, так что ни о чём думать не надо.

Как же использовать движок ачивок в своих проектах? Во-первых надо добавить мовиклип achInfo на главную временную линейку. Его можно кастомизировать под стиль игры. Проще всего скопировать его из примера. Назовём этот экземпляр «achInfoClip».

Потом в классе ach в функции loadAllAch() записываем те ачивки, которые нам нужны. Можно конечно и напрямую вызывать addAchToDB(…) из главной программы. Это кому как удобно.

Далее инициализируем движок ачивок:

ach.init('myAch',achInfoClip);

где первый параметр – имя куки, в который будут сохранятся достижения, второй – имя нашего информационного мовиклипа.

Далее можно загрузить старые значения ачивок:

ach.loadAchFromCookie();

и можно уже получать достижения для простых ачивок есть функция:

ach.getAch('lev1');

для ачивок с параметром:

ach.incAchCnt('kill5');

Вот собственно и всё. Класс ach уже сам определит, была ли взята ачивка или нет. Если ещё нет – покажет информацию по ачивке через мовиклип achInfoClip. И конечно же сохранит результат в файл куки. Думаю довольно удобно.

Обнулить все результаты ачивок можно следующей функцией:

ach.initAchCookie();

Сам же код примера выглядит следующим образом. Из комментариев думаю всё ясно:

 
import main.*;
 
//инициализация движка ачивок
ach.init('myAch',achInfoClip);
 
//также нам потребуется звук
sounds.init(500,400);
 
//Загружаем старые ачивки
ach.loadAchFromCookie();
 
//Обновление информации по ачивкам
function updateTXT():void 
{
	txt.text="Achievements:\n\n";
	var iobj:String;
	for(iobj in ach.db)
	{
		txt.appendText(ach.db[iobj].title+' ');
		txt.appendText(ach.db[iobj].active?'on':'off');
 
		//Если ачивка количественная - выводим сколько осталось в процентах
		if(ach.db[iobj].cntNeed>0)
			txt.appendText('   completed '+ach.db[iobj].cntCur/ach.db[iobj].cntNeed*100+'%');
 
		txt.appendText('\n');
	}
 
 
}
updateTXT();
 
//кнопки получения ачивок
but1.addEventListener(MouseEvent.CLICK, but1_Click);
function but1_Click(e : MouseEvent):void 
{
	ach.getAch('lev1');
	updateTXT();
}	
 
but2.addEventListener(MouseEvent.CLICK, but2_Click);
function but2_Click(e : MouseEvent):void 
{
	ach.getAch('dropAb');
	updateTXT();
}	
 
but3.addEventListener(MouseEvent.CLICK, but3_Click);
function but3_Click(e : MouseEvent):void 
{
	ach.incAchCnt('kill5');
	updateTXT();
}	
 
//Стереть все записанные ачивки
but4.addEventListener(MouseEvent.CLICK, but4_Click);
function but4_Click(e : MouseEvent):void 
{
	ach.initAchCookie();
	updateTXT();
}

Класс ach – главный класс движка ачивок. Здесь происходит всё управление:

package main 
{ 
     public class ach 
	 {
		   static public var db:Object=new Object(); //Все ачивки здесь
		   static public var achInfoMC:achInfo; //Мовиклип с инфой по ачивке
		   static public var cookieName:String; //Имя куки файла куда пишем ачивки
 
 
		   //Внутрение переменные
		   static private var iobj:String;
		   static private var myCookie:Cookie;
 
		   //создаём ачивки. Можно конечно вызывать извне класса но думаю так удобней
		   static public function loadAllAch() 
		   { 	
				addAchToDB("lev1","Beginner","Complete the first level.");
				addAchToDB("dropAb","Mad drop","Use 'Drop' ability four times during the battle.");
				addAchToDB("kill5","Warrior","Kill 5 enemies.",5);
 
 
		   }
 
			// Инициализация движка ачивок
			// _cookieName - имя кукиса куда пишем взятые ачивки
			// _achInfoMC - имя мовиклипа, отвечающего за отображение инфы по взятой ачивке
		   static public function init(_cookieName:String,_achInfoMC:achInfo) 
		   { 
		   		achInfoMC=_achInfoMC;
				cookieName=_cookieName;
 
				myCookie=new Cookie(cookieName);
 
				loadAllAch();	
           }
 
			// Добавление ачивки базу
			// _achName - имя ачивки по которой будем её вызывать
			// _achTitle - отображаемое имя ачивки
			// _achDsc - описание ачивки
			// _achCnt - если не ноль - ачивка с параметром
		   static public function addAchToDB(_achName:String,_achTitle:String,_achDsc:String,_achCnt:int=0) 
		   { 
				db[_achName]=new achItem(_achName,_achTitle,_achDsc,_achCnt);
		   }
 
		   // Загрузка ачивок из кукисов
		   static public function loadAchFromCookie() 
		   {
				for(iobj in db)
				{
					db[iobj].active=Boolean(myCookie.get(iobj+'_active'));
					db[iobj].cntCur=int(myCookie.get(iobj+'_cntCur'));
				}
		   }
 
		   // Обнуление всех ачивок
		   static public function initAchCookie() 
		   {
				for(iobj in db)
				{
					myCookie.putNoFlush(iobj+'_active',0);
					myCookie.putNoFlush(iobj+'_cntCur',0);
					db[iobj].active=false;
					db[iobj].cntCur=0;
				}
				myCookie.flushData();
		   }
 
		   // Записать получение ачивки с именем ach_name
		   static public function getAch(ach_name:String) 
		   {
			    //Берём ачивку только если она уже не взята
			   	if(!db[ach_name].active)
				{
		   			db[ach_name].active=true;
					if(sounds) sounds.PlaySnd("snd_ach");
					achInfoMC.showAch(ach.db[ach_name]);
					myCookie.put(ach_name+'_active',db[ach_name].active);
					return true;
				}
				return false;
		   }
 
		   // Установить параметр ачивки ach_name в значение ach_cnt
		   static public function setAchCnt(ach_name:String,ach_cnt:int) 
		   {
			   	if(!db[ach_name].active)
				{
		   			db[ach_name].cntCur=ach_cnt;
					myCookie.put(ach_name+'_cntCur',db[ach_name].cntCur);
 
					//Если параметр ачивки достиг максимального значения - получаем ачивку
					if(db[ach_name].cntCur>=db[ach_name].cntNeed)
					{
						db[ach_name].active=true;
						db[ach_name].cntCur=db[ach_name].cntNeed;
						if(sounds) sounds.PlaySnd("snd_ach");
						achInfoMC.showAch(ach.db[ach_name]);
						myCookie.put(ach_name+'_active',db[ach_name].active);
						return true;
					}
				}
				return false;
		   }
 
		   // Увеличить на единицу параметр ачивки ach_name
		   static public function incAchCnt(ach_name:String) 
		   {
			   setAchCnt(ach_name,db[ach_name].cntCur+1);
		   }
	 }
}

Класс achItem – описывает одну ачивку. В этом классе хранится только информация:

package main 
{ 
     public class achItem 
	 {
		   public var name:String; //имя ачивки по которой будем её вызывать
		   public var title:String; //отображаемое имя ачивки
		   public var desc:String; //описание ачивки
 
		   public var active:Boolean; //взята ли ачивка
 
		   public var cntNeed:int; //если не ноль - ачивка с параметром
		   public var cntCur:int; //текущее значение параметра ачивки
 
	 	   //Конструктор класса ачивки - все пораметры соотвествуют названиям выше )
		   public function achItem(_name:String,_title:String,_desc:String,_cntNeed:int=0) 
		   {
			    name=_name;
 				title=_title;
				desc=_desc;
				cntNeed=_cntNeed;
 
				cntCur=0;
				active=false;
           } 
	 }
}

Класс achInfo – панелька с информацией, которая выскакивает каждый раз, когда мы берём ачивку. Её легко кастомизировать под свой проект. Хочу обратить внимание на мовиклип achPic. В нём хранятся все пиктограммы достижений. Все кадры в нем поименованы так же, как и ачивки в программе. Однако если такой пиктограммы нет, то будет выбрана пиктограмма по-умолчанию – первый кадр с именем ‘ok’.

package main 
{ 
	import flash.utils.*;
	import flash.events.*;
     public class achInfo extends alphaFader 
	 {
		   //Время показа инфы по взятой ачивке
		   private const TIME_TO_SHOW:int=4000;
 
		   //таймер для исчезновения этого мовиклипа
		   private var removeTimer:Timer;
 
		   public function achInfo() 
		   {
 				removeTimer= new Timer(TIME_TO_SHOW,1);
				removeTimer.stop();
				removeTimer.addEventListener(TimerEvent.TIMER, removeTimer_Timer);	
				visible=false;
 
           } 
 
		    //Показать эту панель с инфой по ачивке thisAch
			public function showAch(thisAch:achItem):void 
			{
				achObj.achPic.gotoAndStop(thisAch.name);
				achObj.titleTxt.text=thisAch.title;
				achObj.descTxt.text=thisAch.desc;
				removeTimer.start();
				startFadeIn();
			}
 
		    //Плавное исчезновение панели
			function removeTimer_Timer(event:TimerEvent):void 
			{
				startFadeOut();
			}
	 }
}

Весь код примера можно скачать здесь: http://www.anegmetex.com/devblog/files/achEngine.rar

Звуковой класс может воспроизводить только одиночные звуки. Петли и зацикленные эффекты планируется добавить в будущем. Просто пока мне это было не нужно в предыдущих играх класс может также воспроизводить объемный звук, учитывая расстояние до объекта и его положение относительно слушателя.

Музыкальный класс может воспроизводить зациклено музыкальные треки а также обеспечивать плавную смену музыки путём затухания.

Классы все статические, поэтому создавать их экземпляры не требуется. У всех классов можно менять громкость и отключать звук.

Смотрим пример (жмём на жёлтые кружочки, чтобы было весело):

Использовать класс sounds весьма просто. Для начала надо в функции init написать те, звуки которые будут загружены:

//Здесь втыкаем свои звуки
snd['mysnd'] = new mysnd();

потом надо инициализировать класс в основной программе:

sounds.init(500,400);

Вот вообщем-то и всё! Теперь мы можем вызывать воспроизведение звука где нам это необходимо:

sounds.PlaySnd('mysnd',1,b1);

первый параметр это имя звука, которое мы задали в функции init. Второй – это сила звука, для взрывов например можно ставить 2 или 3. Последний параметр это эмиттер звука. Его координаты будут использованы для расчёта затухания звука, а также его панорамирования. Если задать только имя звука – он будет воспроизведён без учёта положения. Все звуки воспроизводятся относительно координат sounds.cenX и sounds.cenY. По умолчанию это центр экрана (все расчёты ведутся в глобальных координатах Stage). Также можно привязать слушателя к конкретному объекту, для этого необходимо будет менять cenX и cenY в основной программе (не забывая переводить координаты в глобальную систему координат).

Громкость звуков можно менять с помощью переменной sounds.vol. Отключить все звуки можно задав переменной sounds.sndEnable=false.

Класс sounds:

// Управление пространственными звуками в игре
package main {
	import flash.media.SoundTransform;
	import flash.display.*;
	import flash.utils.*;
	import flash.geom.*;
 
	dynamic public class sounds extends Object 
	{
		static var snd:Object;	// хэш со звуками
		static var stageRadius:Number; // примерный радиус видимой области
		static public var vol:Number=0.9; // громкость
		static public var sndEnable:Boolean=true; // включён ли звук
 
		//Координаты слушателя
		static public var cenX:Number=0;
		static public var cenY:Number=0;
 
		//внутренние переменные
		static var v:ageVector= new ageVector();
		static var p:Point;
 
		//Инициализация класса. Передаём в функцию размеры флешки
		static public function init(stageWidth:Number, stageHeight:Number) 
		{
			// создадим хеш звуков
			snd = new Object();
 
			//Здесь втыкаем свои звуки
			snd['mysnd'] = new mysnd();
 
			// вычислим примерный радиус видимой области экрана
			stageRadius = (stageWidth)/1.4;			
 
			//Центр по умолчанию в центре экрана. Можно привязать к какому-либо объекту
			cenX=stageWidth*0.5;
			cenY=stageHeight*0.5;
 
		}
 
 
		// Воспроизводит звук с учетом пространства
		// snd_name - имя звука
		// dv - множитель для громкости		
		// obj - эмиттер звука
		static public function PlaySnd(snd_name:String,dv:Number=1.0,obj:*=null):void 
		{
			var t:SoundTransform;
 
			//Если звук отключён - выходим
			if(!sndEnable || vol<0.001) return;
 
			//Без объёмного звука
			if(obj==null)
			{
 
				t = new SoundTransform();
				t.volume = vol;
				snd[snd_name].play(0, 0, t);
 
			}
			else
			{
 
				t= new SoundTransform();
 
				//Все расчёты ведём в глобальной системе координат
				p=obj.parent.localToGlobal(new Point(obj.x,obj.y));
 
				v.x=p.x-cenX;
				v.y=p.y-cenY;
 
				// Ставим громкость в зависимости от расстояния
				t.volume = ageMath.trimToRange(vol * ageMath.RemapVal(v.len(),0,dv * stageRadius,1,0),0,1);
 
				// стерео в зависимости от положения источника звука
				t.pan = ageMath.trimToRange(ageMath.RemapVal(v.x,-stageRadius/2,stageRadius/2,-1,1),-1,1);
 
				// воспроизводим
				snd[snd_name].play(0, 0, t);
			}
		}
 
	}
}

Класс музыки musicEnv инициализируется аналогичным образом. В init прописываем все треки которые будут использованы в нашей игре.

//Здесь втыкаем свои муз треки
mus['mus1'] = new mus1();
mus['mus2'] = new mus2();
mus['mus3'] = new mus3();

далее в основной программе инициализируем класс с музыкой:

musicEnv.init();

и его уже можно использовать! Включаем одну музыку:

musicEnv.fadeTo('mus1');

потом плавно с затуханием меняем на другую:

musicEnv.fadeTo('mus2');

а так можно остановить музыку:

musicEnv.played(false);

чтобы отключить музыку в программе необходимо также использовать переменную sounds.sndEnable:

musicEnv.musEnable=false;
musicEnv.played(false);

включить музыку обратно:

musicEnv.musEnable=true;
musicEnv.played(true);

звук музыки регулируется с помощью переменной sounds.vol, скорость фейдинга – sounds.volFadeSpeed

Класс musicEnv:

// Управление пространственными звуками в игре
package main {
	import flash.media.SoundTransform;
	import flash.display.*;
	import flash.geom.*;
	import flash.utils.*;
	import flash.events.*;
	import flash.media.*;
	dynamic public class musicEnv extends Object 
	{
		static var mus:Object;	// хэш с музыкой
		static public var vol:Number=0.9; // громкость
		static public var volFadeSpeed:Number=0.01; //Скорость фейдинга
		static public var musEnable:Boolean=true; // включёна ли музыка
 
		static public var curMusName:String=""; // Имя текущего трека
 
 
		//внутренние переменные
		static var curCh:SoundChannel; //Текущий канал
		static var offCh:SoundChannel; //Затухающий канал
		static var curVol:Number=0;
		static var curPos:Number=0;
		static var offVol:Number=0;
 
		static var isplayed:Boolean=false;
 
		static var timerVolFader:Timer= new Timer(10);
 
		static var t1:SoundTransform = new SoundTransform();
		static var t2:SoundTransform = new SoundTransform();
 
		static public function init() 
		{
			timerVolFader.stop();
 
			// создадим хеш с музыкой
			mus = new Object();
 
			//Здесь втыкаем свои муз треки
			mus['mus1'] = new mus1();
			mus['mus2'] = new mus2();
			mus['mus3'] = new mus3();
		}
 
		//Плавная смена трека на musname
		static public function fadeTo(musname:String) 
		{
			curMusName=musname;
 
 
			//Если музыка отключена - выходим
			if(!musEnable) return;
 
			isplayed=true;
 
			var t:SoundTransform;
			t = new SoundTransform();
			t.volume = 0;
 
			if(offCh) offCh.stop();
			offCh=curCh;
 
			curCh=mus[musname].play(0, int.MAX_VALUE, t);
 
			curVol=0;
			offVol=vol;
 
			if(!timerVolFader.running)
			{
				timerVolFader.addEventListener(TimerEvent.TIMER, timerVolFader_Timer, false, 0, true);
				timerVolFader.start();
			}
 
		}
 
		//Остановить или запустить воспроизведение музыки
		static public function played(flg:Boolean):void 
		{
			if(flg==isplayed) return;
 
			if(flg)
			{
				if(curMusName!="") fadeTo(curMusName);
			}
			else
			{
				isplayed=false;
 
				if(curCh) 
				{
					curCh.stop();
					curPos=curCh.position;
				}
				if(offCh) offCh.stop();
				offVol=0;
				curVol=vol;
 
				if(timerVolFader.running)
				{
					timerVolFader.stop();
					timerVolFader.removeEventListener(TimerEvent.TIMER, timerVolFader_Timer);
				}
			}
		}
 
		//Плавный фейдинг музыки
		static public function timerVolFader_Timer(event:TimerEvent):void 
		{
 
 
			if(offCh!=null)
			{
				if(offVol>0)
					offVol -= volFadeSpeed;
				else
					offVol=0;
 
				t1.volume = offVol;
				offCh.soundTransform=t1;
			}
 
			if(curCh!=null && (offVol<vol/2 || offCh==null))
			{
				if(curVol<vol)
					curVol += volFadeSpeed;
				else
					curVol=vol;
 
				t2.volume = curVol;
				curCh.soundTransform=t2;
			}
 
 
			//Если достигли порогового значения громкости
			if(curVol>vol)
			{
				if(offCh!=null) offCh.stop();
				timerVolFader.stop();
				timerVolFader.removeEventListener(TimerEvent.TIMER, timerVolFader_Timer);
			}
		}
	}
}

Вот вообщем то и всё. Думаю новичкам класс может пригодиться. Исходники примера тут: http://www.anegmetex.com/devblog/files/SoundAndMusic.rar

под катом остальные цифирьки:

В этот месяц очень озаботился возможными недействительными кликами на портале, боюсь как бы гугл не забанил мой аккаунт. Поэтому под конец месяца поменял рекламу рядом с игрой на CPMStar. Ну и вцелом баннеры лучше выделил. Доход конечно стал меньше, но думаю в конечном счёте так лучше будет. Гугл обещает что чем меньше процент недействительных кликов тем больше CPM. Пока этого не заметно, но будем надеяться на лучшее

Рекламой в играх за март удалось заработать:
Доход от CPMStar: $1015.01
Доход от Mochi: $85.64
Суммарный доход с игр: $1100.65

Frustra Bit к сожалению пошёл не очень хорошо, так что на данный момент всего 243к геймплеев… конверсия 11%. Зато Тед набрал за полтора месяца уже 2 ляма геймплеев. Вообщем мораль – надо делать хитовые игры на треше далеко не уедешь… Всего с сайтлоков Frustra Bit получилось $300.

Всего за месяц получается удалось заработать $1892.57

вообщем такие дела.

На днях мой портальчик переехал на новый сервер. К сожалению, старого уже стало не хватать, и я реально боялся к концу месяца вылезти за лимиты трафика. Меня очень часто спрашивают какой у меня хостинг, поэтому сообщаю – теперь я располагаюсь на сервере компании quickweb. Мне эта кампания понравилась во-первых только отличными ревью на webhostingtalk (ниже 9\10 я не нашёл), во-вторых бодрыми тарифными планами с большим выделенным трафиком и гигабитной скоростью подключения (для меня это весьма критично стало), и в третьих, что их сервера находятся в известном в узких кругах датацентре Softlayer. Взял пока 2-й тариф, но с оглядкой, что есть простор у хостера для апгрейда на более мощные конфиги. (очень уж я не люблю переезжать от хостера к хостеру…)

Но так как я парень, который «постоянно всё считает» (С) Alex_Spil после оплаты хостинга меня начало сильно ломать платить ещё за контрольную панель половину от цены хостинга. Учитывая, что я захожу в неё дай бог пару раз в месяц, и то чтобы проверить всё ли окей. Но без неё я не мог. Да я хоть и бородатый, но не админ, и поэтому сконфигурировать линух из консоли мне весьма трудно и неохота.

Поэтому я стал искать бесплатные альтернативы, и, перекопав кучу инфы, я нашёл одну отличную разработку – Kloxo.
Устанавливается это чудо весьма просто из ssh:

# wget http://download.lxlabs.com/download/kloxo/production/kloxo-install-master.sh
# sh kloxo-install-master.sh

вот и всё! Удивительно, но даже с установкой платного directAdmin-a мне пришлось дольше возиться, были какие то проблемы со входом и паролем.

Думаете панель шлак? А вот и нет. Панель напоминает cPanel. Мне она показалась даже дружелюбней чем тот же прямойАдмин. Клоксо заботливо после входа напомнил мне добавить домен, потом напомнил завести мейл, потом посоветовал настроить ftp. Вообщем весьма дружелюбная к пользователю панель, и весьма интуитивно понятная. Выглядит примерно так
http://techore.otterwedding.com/wp-content/uploads/2009/12/ipaddresses.png

В ней есть всё что необходимо для менеджмента VPS: и настройка доменов, и DNS, и FTP, и mail, и mysql – вообщем все то, что нужно для счастья. Кроме того, в ней встроена система статистики по доменам и много других вкусностей которые я ещё до конца изучить не успел. И главное – она абсолютно бесплатна!

http://onlinegamer.cc/Action/309/Frustra-Bit.html

Пошла довольно неплохо на Ньюграунде, заняла Daily 3rd Place и попала на фронтпейдж. С дистрибьюцией тоже вроде пока всё норм. На конге как всегда игру жёстко заминусовали ) лишь только комментарии типа «Loved it. Best maze game on kong» греют душу

Уровень с тетрисом как и ожидалось всех повесилил Ну и в целом комменты были весьма одобряющие. (иногда прям читаешь и думаешь ну кто же там тогда минусует?)

Да, кстати, во время разработки столкнулся с неприятной особенностью mochi api. Дело в том, что в этой игре я использовал полноэкранный эффект, по типу того, что описывался мной здесь. Рисую весь экран в битмапдату, потом размываю и накладываю с умножением на текущую картинку. Но оказалось, что функция draw(this,…), которая рендит весь экран в битмапдату, перестаёт нормально работать, после вызова

MochiServices.connect(”…”, root);

Причём перестаёт работать в релиз-билде, а в дебаге всё окей! Мда после долгих часов поиска обхода он наконец таки был найден. Если вызвать так:

MochiServices.connect(”…”, stage);

То всё будет нормально. Чудеса да и только.

После встраивания рекламы CPMStar я столкнулся опять с той же проблемой ) короче дело было в security политики, которая запрещала рендер рекламы с другого домена в битмапдату (вероятно с мочи была такая же проблема). Я попытался её разрулить с помощью allowDomain(«cpmstar.com») и в дебаге то опять всё заработало… а вот в релизе, в браузере, всё по-прежнему, с ошибкой. Короче полтора дня промаявшись со всей этой байдой, я просто отключил полноэкранный эффект для прелоадера. И поблагодарил себя за то, что не стал встраивать интерлевел рекламу ) иначе это был бы пипец. Так что, товарищи, имейте ввиду. Стоит всё таки оборачивать в мовиклип, а не как я – схалявить, и просто рендить весь экран в битмапдату.

под катом много букв и цифр, я предупредил

CTR повысился раза в три, что не может не радовать, среднее количество просмотров пока всё также мало – 2.07, хотя конечно трафик не качественный, так что вполне ожидаемо. Среднее время пребывания – 2:29. Количество новых визитов – 87%. Баунс рейт весьма снизился, с 70% до 57%, что довольно хорошо. По странам трафик сильно размыт, на первом месте США, потом Россия и Бразилия, но их доля не так значительна в процентном соотношении (11%, 10% и 9% соответственно).

Поисковый траф всё также мизерный, составляет 0.24%. Над этим надо будет работать. Кстати у меня на сайте объявился заядлый комментатор, уже настрочил аж 74 комментария, да и не просто односложных, а весьма развёрнутых. Эх, таких бы мне штук десять, тогда бы думаю мой портал лучше воспринимался бы поиском гугла

Статистика по игре Stark Raving Ted
Теперь статистика по игре про Теда. Всего в игру за две недели сыграли 914k раз. Что удивило: хоть игра и получила довольно низкую оценку на конге, и средненькую на ньюграунде (и соответственно не была зафичена ни одним из них), но её довольно не хило начали расхватывать, хотя я её тогда даже не успел залить на FGD и Мочи. Игра была взята практически всеми большими порталами. Отдельно хочется упомянуть Джона из НотДопплера, он прежде чем добавить игру к себе на портал, сначала разрешение спросил, потом поинтересовался какой рейтинг игре присвоить, а после, как добавил, ещё и спросил “всё ли хорошо, может чего-то изменить?”. Вежливый такой

Ладна, от лирики к фактам. Всего по внутренним кнопкам переходов из игры на сайт было 132 628 + 55 295 по кнопке walkthrough. Соответственно конверсия составила около 20.6%, что очень хорошо. Ещё раз убеждаюсь, что прелоадер с полностью активной зоной для клика решает. Если опираться на цифры – почти 59% переходов – это переходы по прелоадеру (тут я НЕ учитывал клики по кнопкам walkthrough). Вы наверно подумаете, что люди кликают часто по ошибке, и баунс рейт поэтому высокий, а вот и нет: всего 46%. По тому же сплешу баунс рейт 62%. Среднее время пребывания на сайте почти одинаковое. Такой же прелоадер был у меня в игре про Санту, и там тоже были такие же показатели. А вот в Escaped прелоадер был “не правильный” и как результат – конверсия смешные 6%… поэтому я уже для себя вывод сделал – прелоадеры у меня будут впредь только “правильными”

Так, если по доходам на портале, то Тед принёс $200.16 (включая $11.02 по кнопочке walkthrough). Значит если бы я не зарелизил Теда, то портал бы принёс около $78.88, что вообщем то тоже больше, чем в предыдущем месяце )

По рекламе внутри игры Тед принёс:
CPMStar $615.47 (dev) + $184.69 (sponsor) = $800.16
Mochi $10.82

В мочи я добавил Теда лишь дня три назад, так что цифра не особо отражает реальное соотношение между рекламными сетями. Также хочется похвалиться, что Теда таки зафичили на Мочи

Всего же на внутригровой рекламе в этом месяце CPMStar и Mochi было заработано $923.09 и $11.98 соответственно.

Как итог в этом месяце было заработано:
сайтом – $280
реклама в играх – $935.07
сайтлоки Теда – $605
Итого – $1820.07 (из них $1616.17 – игра про Теда)

Меня пару раз спрашивали в блоге – выгоднее ли спонсировать игры самому? Максимальная ставка на аукционе за Теда была $1500… Думаю конкретно по данной игре для меня вышло куда выгоднее спонсировать самому

Ну и ещё хочется вспомнить одного анонимного хейтера, который в комменте выразил своё безусловно профессиональное мнение, что игра не отобьёт даже $1500 баксов… что тут скажешь, ты облажался, дурень! Отбила, всего за две недели.

Вот на этом и всё пожалуй. Надеюсь этот поток букв и цифр оказался кому-то полезным.

P.S. И ещё я надеюсь, что нигде не обсчитался ))

Ура! Наконец-то, я всё-таки нашёл в себе силы чтобы закончить эту игру пролежав на диске более полугода игра таки увидела свет в конце тоннеля. Тед отправился спасать мир на экранах тысяч игроков

http://onlinegamer.cc/Shooter/238/Stark-Raving-Ted.html

Игра получила довольно вялые оценки на НГ и Конге и не попала ни в один фичед лист, однако дистрибуция пошла невероятно хорошо (по крайней мере для меня и моих игр). Я её даже не запостил на FGD и мочи (да вообще по сути не занимался дистрибьюцией), а её за два дня уже расхватали на 250+ хостов. Вчера в игру поиграло более 100к игроков. Сегодня наверно будет ещё больше. Думаю для меня это пока самая успешная игра из всех 7 выпущенных на данный момент игр

Я очень рад что не отдал эту игру за бесценок на FGL. Вообще сейчас пока планирую поработать на свой портал а не на спонсоров. Ведь делать игры для игроков намного приятней чем для спонсоров.

Да ну и ещё что приятно – игроки ни разу не пнули меня по поводу engrish-а, хотя текстов и диалогов в игре довольно много. Значит мой английский всё-таки выправляется потихоньку

подробности под катом

По трафику уже не плохо стало – на первом месте США, на втором – Германия. Однако их доля не так велика и трафик довольно размыт на другие страны. Количество возвращающихся игроков увеличилось до 14% что не может не радовать время посещения тоже растёт.

Статистика по игре “Escaped!”
Вообщем игра получилась довольно противоречивой с рискованным сеттингом, было много плохих оценок только из-за того что человек ожидал шутер а получил пазл Кроме того конверсия получилась весьма низкой – чуть больше 6%, по сравнению с игрой про санту где конверсия была около 21%. Наверно связано это с тем что в игре нет прохождения и прелоадер в санте был более удачным, с него переходов было очень много. Ну и конечно в санте не было рекламы Тем не менее ошибки будут учтены и в следующей игре надеюсь конверсия будет минимум 10%. Ах да, ещё злобный сайт moFunZone блокирует все исходящие ссылки просмотров много а толку никакого.

Итак, за 17 дней с момента релиза в игру поиграли чуть более 500к человек (в статистике я не учитываю сайтлоки, только мою виральную версию). На рекламе за этот срок удалось заработать всего $323.43. На версии с CPMStar $244.25+$73.29 и на версии с мочи ЦЕЛЫХ $5.89

Плюс с сайтлоками получилось за январь порядка $650, вообщем уже можно как то пытаться существовать и без спонсоров вообще мне приятнее делать игру непосредственно для игроков, а не для спонсоров.

Вот вроде всё пока

http://onlinegamer.cc/Puzzle/186/Escaped.html

Игра представляет собой в некотором роде переосмысление и доработку моей старой игры Toy Tales )
Геймплей был серьёзно переработан, исправлен баланс, прикручены ачивменты, добавлены разные эффекты плюс переработана вся звуковая и визуальная составляющая игры. В целом игра стала динамичней и думаю интересней

Что особенно приятно так это то, что игра побывала на первой странице порталов Kongregate и Newgrounds:

С конга конечно уже вылетела благодаря хейтерам, но на НГ пока держится

Кстати немного о CPMStar, игра в сумме за вчерашний день, только с конга и нг собрала на рекламе 52$. 39,5$ разработчику и 12,5$ спонсору, но так как я являюсь и тем и другим… ну вы поняли почему я в предыдущем посте так радовался))

Вообщем думаю игра мне принесет много трафика на портал. Следующим релизом запланирован Stark Raving Ted, надеюсь с ним тоже попасть на главную